fn pub static new(a: Int, b: Int, c: Int, d: Int) -> Ipv4Address {
  Ipv4Address(a: a, b: b, c: c, d: d)
}

fn pub static parse(input: String) -> Option[Ipv4Address] {
  # No IPv4 address can be longer than 15 characters (255.255.255.255).
  if input.size > 15 { return Option.None }

  let segments = []
  let format = Format.Decimal

  input.split('.').each(fn (segment) {
    # This handles inputs such as "." and "..."
    if segment.empty? { return }

    # We don't support octal formats, as it was never part of the spec.
    # Ignoring them can lead to security issues, as described in
    # https://www.bleepingcomputer.com/news/security/go-rust-net-library-affected-by-critical-ip-address-validation-vulnerability/.
    if segment.byte(0) == ZERO_BYTE and segment.size > 1 { return }

    match Int.parse(segment, format) {
      case Some(int) if int >= IP_MINIMUM_VALUE and int <= IPV4_OCTET_MAXIMUM
      -> {
        segments.push(int)
      }
      case _ -> {}
    }
  })

  if segments.size != IPV4_OCTETS { return Option.None }

  Option.Some(
    Ipv4Address(
      a: segments.get(0),
      b: segments.get(1),
      c: segments.get(2),
      d: segments.get(3),
    ),
  )
}

fn pub !=(other: T) -> Bool {
  (self == other).false?
}

fn pub ==(other: ref Ipv4Address) -> Bool {
  @a == other.a and @b == other.b and @c == other.c and @d == other.d
}

fn pub broadcast? -> Bool {
  @a == IPV4_OCTET_MAXIMUM
    and @b == IPV4_OCTET_MAXIMUM
    and @c == IPV4_OCTET_MAXIMUM
    and @d == IPV4_OCTET_MAXIMUM
}

fn pub clone -> Ipv4Address {
  Ipv4Address(a: @a, b: @b, c: @c, d: @d)
}

fn pub documentation? -> Bool {
  if @a == 192 and @b == 0 and @c == 2 { return true }

  if @a == 198 and @b == 51 and @c == 100 { return true }

  @a == 203 and @b == 0 and @c == 113
}

fn pub fmt(formatter: mut Formatter) {
  formatter.write(to_string)
}

fn pub move into_string -> String {
  to_string
}

fn pub link_local? -> Bool {
  @a == 169 and @b == 254
}

fn pub loopback? -> Bool {
  @a == 127
}

fn pub multicast? -> Bool {
  let first = @a

  first >= 224 and first <= 239
}

fn pub private? -> Bool {
  if @a == 10 { return true }

  if @a == 172 and @b >= 16 and @b <= 31 { return true }

  @a == 192 and @b == 168
}

fn pub to_ipv6_compatible -> Ipv6Address {
  Ipv6Address.new(
    0,
    0,
    0,
    0,
    0,
    0,
    octets_to_hextet(@a, @b),
    octets_to_hextet(@c, @d),
  )
}

fn pub to_ipv6_mapped -> Ipv6Address {
  Ipv6Address.new(
    0,
    0,
    0,
    0,
    0,
    IPV6_HEXTET_MAXIMUM,
    octets_to_hextet(@a, @b),
    octets_to_hextet(@c, @d),
  )
}

fn pub to_string -> String {
  '${@a}.${@b}.${@c}.${@d}'
}

fn pub unspecified? -> Bool {
  @a == 0 and @b == 0 and @c == 0 and @d == 0
}